mirror of
https://github.com/melonDS-emu/melonDS.git
synced 2024-11-14 13:27:41 -07:00
109 lines
3.3 KiB
CMake
109 lines
3.3 KiB
CMake
cmake_minimum_required(VERSION 3.15)
|
||
|
||
cmake_policy(VERSION 3.15)
|
||
if (POLICY CMP0076)
|
||
cmake_policy(SET CMP0076 NEW)
|
||
endif()
|
||
|
||
set(CMAKE_POLICY_DEFAULT_CMP0069 NEW)
|
||
|
||
set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
|
||
|
||
project(melonDS
|
||
VERSION 0.9.4
|
||
DESCRIPTION "DS emulator, sorta"
|
||
HOMEPAGE_URL "https://melonds.kuribo64.net"
|
||
LANGUAGES C CXX)
|
||
|
||
include(CheckSymbolExists)
|
||
include(CheckLibraryExists)
|
||
include(CMakeDependentOption)
|
||
include(CheckIPOSupported)
|
||
|
||
set(CMAKE_OSX_DEPLOYMENT_TARGET "10.15" CACHE STRING "Minimum OS X deployment version")
|
||
|
||
set(CMAKE_C_STANDARD 11)
|
||
set(CMAKE_C_STANDARD_REQUIRED ON)
|
||
set(CMAKE_CXX_STANDARD 17)
|
||
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
||
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
|
||
|
||
add_compile_definitions(MELONDS_VERSION="${melonDS_VERSION}")
|
||
|
||
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
|
||
set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
|
||
set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
|
||
endif()
|
||
|
||
function(detect_architecture symbol arch)
|
||
if (NOT DEFINED ARCHITECTURE)
|
||
set(CMAKE_REQUIRED_QUIET 1)
|
||
check_symbol_exists("${symbol}" "" ARCHITECTURE_${arch})
|
||
unset(CMAKE_REQUIRED_QUIET)
|
||
|
||
# The output variable needs to be unique across invocations otherwise
|
||
# CMake's crazy scope rules will keep it defined
|
||
if (ARCHITECTURE_${arch})
|
||
set(ARCHITECTURE "${arch}" PARENT_SCOPE)
|
||
set(ARCHITECTURE_${arch} 1 PARENT_SCOPE)
|
||
add_definitions(-DARCHITECTURE_${arch}=1)
|
||
endif()
|
||
endif()
|
||
endfunction()
|
||
|
||
detect_architecture("__x86_64__" x86_64)
|
||
detect_architecture("__i386__" x86)
|
||
detect_architecture("__arm__" ARM)
|
||
detect_architecture("__aarch64__" ARM64)
|
||
|
||
cmake_dependent_option(ENABLE_JIT "Enable JIT recompiler" ON
|
||
"ARCHITECTURE STREQUAL x86_64 OR ARCHITECTURE STREQUAL ARM64" OFF)
|
||
cmake_dependent_option(ENABLE_JIT_PROFILING "Enable JIT profiling with VTune" OFF "ENABLE_JIT" OFF)
|
||
option(ENABLE_OGLRENDERER "Enable OpenGL renderer" ON)
|
||
|
||
check_ipo_supported(RESULT IPO_SUPPORTED)
|
||
cmake_dependent_option(ENABLE_LTO_RELEASE "Enable link-time optimizations for release builds" ON "IPO_SUPPORTED" OFF)
|
||
cmake_dependent_option(ENABLE_LTO "Enable link-time optimizations" OFF "IPO_SUPPORTED" OFF)
|
||
|
||
if (ENABLE_LTO_RELEASE)
|
||
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE)
|
||
endif()
|
||
|
||
if (ENABLE_LTO)
|
||
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
|
||
endif()
|
||
|
||
set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Og")
|
||
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Og")
|
||
set(CMAKE_C_FLAGS_RELEASE "-O3")
|
||
set(CMAKE_CXX_FLAGS_RELEASE "-O3")
|
||
|
||
if (NOT APPLE)
|
||
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} -s")
|
||
endif()
|
||
|
||
if (WIN32)
|
||
option(BUILD_STATIC "Statically link dependencies" OFF)
|
||
endif()
|
||
|
||
if (BUILD_STATIC AND WIN32)
|
||
set(CMAKE_FIND_LIBRARY_SUFFIXES .a)
|
||
endif()
|
||
|
||
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
|
||
|
||
find_program(CCACHE "ccache")
|
||
if (CCACHE)
|
||
message(STATUS "Using CCache to speed up compilation")
|
||
set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE})
|
||
set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE})
|
||
endif()
|
||
|
||
option(BUILD_QT_SDL "Build Qt/SDL frontend" ON)
|
||
|
||
add_subdirectory(src)
|
||
|
||
if (BUILD_QT_SDL)
|
||
add_subdirectory(src/frontend/qt_sdl)
|
||
endif()
|