mirror of
https://github.com/melonDS-emu/melonDS.git
synced 2024-11-14 13:27:41 -07:00
ddf9a5ac27
* CMake build fixups
* Correctly set C/C++ standard
* Specify CXX in project() to get things set up right, also causes it to
link using the C++ compiler which is necessary for LTO builds with Clang
to work right
* Remove Fedora/flatpak build workaround, no longer needed with C++ standard set
* Link libm explicitly if we need to
* Specify -fuse-linker-plugin when building with LTO just in case
* Restore CMAKE_{C,CXX}_STANDRD, oops
* Use C++17
92 lines
2.1 KiB
CMake
92 lines
2.1 KiB
CMake
cmake_minimum_required(VERSION 3.13)
|
|
|
|
include(CheckSymbolExists)
|
|
include(CheckLibraryExists)
|
|
|
|
cmake_policy(VERSION 3.13)
|
|
if (POLICY CMP0076)
|
|
cmake_policy(SET CMP0076 NEW)
|
|
endif()
|
|
|
|
project(melonDS CXX)
|
|
|
|
set(CMAKE_C_STANDARD 11)
|
|
set(CMAKE_CXX_STANDARD 17)
|
|
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
|
|
|
|
check_library_exists(m pow "" LIBM)
|
|
if(LIBM)
|
|
link_libraries(m)
|
|
endif()
|
|
|
|
if (NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE Release)
|
|
endif()
|
|
|
|
function(detect_architecture symbol arch)
|
|
if (NOT DEFINED ARCHITECTURE)
|
|
set(CMAKE_REQUIRED_QUIET 1)
|
|
check_symbol_exists("${symbol}" "" ARCHITECTURE_${arch})
|
|
unset(CMAKE_REQUIRED_QUIET)
|
|
|
|
# The output variable needs to be unique across invocations otherwise
|
|
# CMake's crazy scope rules will keep it defined
|
|
if (ARCHITECTURE_${arch})
|
|
set(ARCHITECTURE "${arch}" PARENT_SCOPE)
|
|
set(ARCHITECTURE_${arch} 1 PARENT_SCOPE)
|
|
add_definitions(-DARCHITECTURE_${arch}=1)
|
|
endif()
|
|
endif()
|
|
endfunction()
|
|
|
|
detect_architecture("__x86_64__" x86_64)
|
|
detect_architecture("__i386__" x86)
|
|
detect_architecture("__arm__" ARM)
|
|
detect_architecture("__aarch64__" ARM64)
|
|
|
|
if (ARCHITECTURE STREQUAL x86_64 OR ARCHITECTURE STREQUAL ARM64)
|
|
option(ENABLE_JIT "Enable x64 JIT recompiler" ON)
|
|
endif()
|
|
|
|
if (ENABLE_JIT)
|
|
add_definitions(-DJIT_ENABLED)
|
|
endif()
|
|
|
|
if (CMAKE_BUILD_TYPE STREQUAL Release)
|
|
option(ENABLE_LTO "Enable link-time optimization" ON)
|
|
else()
|
|
option(ENABLE_LTO "Enable link-time optimization" OFF)
|
|
endif()
|
|
|
|
option(ENABLE_OGLRENDERER "Enable OpenGL renderer" ON)
|
|
|
|
if (ENABLE_OGLRENDERER)
|
|
add_definitions(-DOGLRENDERER_ENABLED)
|
|
endif()
|
|
|
|
if (CMAKE_BUILD_TYPE STREQUAL Debug)
|
|
add_compile_options(-Og)
|
|
endif()
|
|
|
|
if (CMAKE_BUILD_TYPE STREQUAL Release)
|
|
add_compile_options(-O3)
|
|
add_link_options(-s)
|
|
endif()
|
|
|
|
if (ENABLE_LTO)
|
|
add_compile_options(-flto)
|
|
add_link_options(-flto -fuse-linker-plugin)
|
|
endif()
|
|
|
|
option(BUILD_QT_SDL "Build Qt/SDL frontend" ON)
|
|
|
|
if (WIN32)
|
|
option(BUILD_STATIC "Statically link dependencies" OFF)
|
|
endif()
|
|
|
|
add_subdirectory(src)
|
|
|
|
if (BUILD_QT_SDL)
|
|
add_subdirectory(src/frontend/qt_sdl)
|
|
endif()
|